通达信涨停五基因指标

百日地量:= V=LLV(V,100) AND V>0;

倍量:= VOL>=REF(V,1)*1.9 AND C>REF(C,1);

地量又倍量:COUNT(百日地量,5)>=1 AND COUNT(倍量,1)>=1;{2.倍量过左峰}

N:=20;

左峰高:=REF(HHV(C,N),1);

倍量过左:REF(COUNT(C<左峰高,2)=2,1) AND C>左峰高 AND C>O

AND VOL/REF(VOL,1)>=1.9;{3.回踩黄金线}

{1.黄金柱}

JJ:=(3*C+H+L+O)/6;

VAR1:=DMA(JJ,0.2);

{VAR1:=(8*JJ+7*REF(JJ,1)+6*REF(JJ,2)+5*REF(JJ,3)

+4*REF(JJ,4)+3*REF(JJ,5)+2*REF(JJ,6)+REF(JJ,8))/36;}

TJ1:=VOL=HHV(VOL,10) AND VOL>2*REF(VOL,1) AND CLOSE>VAR1 AND C>REF(C,1);

LJL:=FILTER(TJ1,3);

黄金线:=REF(LOW,BARSLAST(LJL));

黄金柱:=FILTER(TJ1,3);

{2.倍量过左峰}

SR1:=REF(HIGH,10)=HHV(HIGH,2*10+1);

SR2:=FILTER(SR1,10);

SR3:=BACKSET(SR2,10+1);

HD:=FILTER(SR3,10);

前高:=REF(H,BARSLAST(HD));

{倍量:=VOL/REF(VOL,1)>=2 AND COUNT(CLOSE>OPEN,1) OR LOW>REF(HIGH,1) AND COUNT(OPEN>CLOSE,1) AND VOL/REF(VOL,1)>=2;}

突破前高:=CROSS(C,前高);

倍量过左峰:= 突破前高 AND 倍量;

{3.凹口起柱}

T7:=REF(VOL,6)/REF(VOL,7)>=2;

T6:=REF(VOL,5)/REF(VOL,6)>=2;

T5:=REF(VOL,5)/REF(VOL,4)>=1.5;

T4:=REF(VOL,4)/REF(VOL,3)>=1.5;

T3:=REF(VOL,2)/REF(VOL,3)>=1.5;

T1:=V/REF(VOL,1)>2;

T0:=C>O AND C>REF(C,1);

凹口起柱:= T7 AND T1 AND T0

OR T6 AND T1 AND T0

OR T5 AND T1 AND T0

OR T4 AND T1 AND T0

OR T3 AND T1 AND T0 ;

{凹口起柱}

AKQZ:= 黄金柱 AND 凹口起柱;

{4.前高低位}

X:=21;

TTY:=H;

AAT:=REF(TTY,X)=HHV(TTY,2*X+1);

BBT:=FILTER(AAT,X);

CCT:=BACKSET(BBT,X+1);

HD10T:=FILTER(CCT,X);

前期高位:=REF(H,BARSLAST(HD10T));

{突破前高}

TPQG:= 黄金柱 AND 倍量过左峰 AND C>前期高位;

{选股}

回踩黄金线: (COUNT(TPQG,10) OR COUNT(AKQZ,10))

AND COUNT(CROSS(黄金线*1.01,L),3)>0 AND L>=黄金线

AND C>REF(C,1) AND REF(C,2)>REF(C,1) AND COUNT(LJL,3)=0;{5.长阴短柱}

长阴短柱: C/REF(C,1)<0.95 AND V<HHV(V,30)/1.9;

{6.1 底同向精准}

NN:=3;

LL0:=0;

L0:=LL0/100;

L1:=ABS(L-REF(L,1))<=L0;

L2:=ABS(L-REF(L,2))<=L0;

L3:=ABS(L-REF(L,3))<=L0;

L4:=ABS(L-REF(L,4))<=L0;

L5:=ABS(L-REF(L,5))<=L0;

精准线:=L1 OR L2 OR L3 OR L4 OR L5;

底精准: FILTER(精准线,NN),COLORCYAN;

 

{6.2 异向并肩精准线}

异向并肩精准: MIN(O,C)=REF(MAX(O,C),1) ;

{4.咬住峰顶线}

FDX:=PEAK(1,10,1);{REF(HHV(H,60),5)};{上一波峰值}

TJ:=BETWEEN(MA(H,3),FDX*0.997,FDX*1.02);

咬住峰顶线: COUNT(TJ,3)>=2,COLORRED;

原理解析：
百日地量赋值: V=100日内V最低值 AND V>0


倍量赋值: 成交量>=1日前的V*1.9 AND C>1日前的C
输出

地量又倍量:统计5日满足百日地量的天数>=1 AND 统计1日满足倍量的天数>=1
{2.倍量过左峰}

N赋值:20


左峰高赋值:REF(N日内C最高值,1)


倍量过左:1日前的统计2日满足C<左峰高的天数=2 AND C>左峰高 AND C>O

AND 成交量/1日前的成交量>=1.9
{3.回踩黄金线}

{1.黄金柱}

JJ赋值:(3*C+H+L+O)/6


VAR1赋值:DJJ的0.2日简单移动平均


{VAR1赋值:(8*JJ+7*1日前的JJ+6*2日前的JJ+5*3日前的JJ

+4*4日前的JJ+3*5日前的JJ+2*6日前的JJ+8日前的JJ)/36
}

TJ1赋值:成交量=10日内成交量最高值 AND 成交量>2*1日前的成交量 AND 收盘价>VAR1 AND C>1日前的C


LJL赋值:TJ1的3过滤


黄金线赋值:REF(最低价,上次LJL距今天数)


黄金柱赋值:TJ1的3过滤


{2.倍量过左峰}

SR1赋值:10日前的最高价=2*10+1日内最高价最高值


SR2赋值:SR1的10过滤


SR3赋值:BACKSET(SR2,10+1)


HD赋值:SR3的10过滤


前高赋值:REF(H,上次HD距今天数)


{倍量赋值:成交量/1日前的成交量>=2 AND 统计1日满足收盘价>开盘价的天数 OR 最低价>1日前的最高价 AND 统计1日满足开盘价>收盘价的天数 AND 成交量/1日前的成交量>=2
}

突破前高赋值:C上穿前高


倍量过左峰:= 突破前高 AND 倍量


{3.凹口起柱}

T7赋值:6日前的成交量/7日前的成交量>=2


T6赋值:5日前的成交量/6日前的成交量>=2


T5赋值:5日前的成交量/4日前的成交量>=1.5


T4赋值:4日前的成交量/3日前的成交量>=1.5


T3赋值:2日前的成交量/3日前的成交量>=1.5


T1赋值:V/1日前的成交量>2


T0赋值:C>O AND C>1日前的C


凹口起柱赋值: T7 AND T1 AND T0

OR T6 AND T1 AND T0

OR T5 AND T1 AND T0

OR T4 AND T1 AND T0

OR T3 AND T1 AND T0


{凹口起柱}

AKQZ赋值: 黄金柱 AND 凹口起柱


{4.前高低位}

X赋值:21


TTY赋值:H


AAT赋值:X日前的TTY=2*X+1日内TTY最高值


BBT赋值:AAT的X过滤


CCT赋值:BACKSET(BBT,X+1)


HD10T:=CCT的X过滤


前期高位赋值:REF(H,上次HD10T距今天数)


{突破前高}

TPQG赋值: 黄金柱 AND 倍量过左峰 AND C>前期高位
输出

{选股}

回踩黄金线: (统计10日满足TPQG的天数 OR 统计10日满足AKQZ的天数)

AND 统计3日满足黄金线*1.01上穿L的天数>0 AND L>=黄金线

AND C>1日前的C AND 2日前的C>1日前的C AND 统计3日满足LJL的天数=0
输出{5.长阴短柱}

长阴短柱: C/1日前的C<0.95 AND V<30日内V最高值/1.9


{6.1 底同向精准}

NN赋值:3


LL0赋值:0


L0赋值:LL0/100


L1赋值:L-1日前的L的绝对值<=L0


L2赋值:L-2日前的L的绝对值<=L0


L3赋值:L-3日前的L的绝对值<=L0


L4赋值:L-4日前的L的绝对值<=L0


L5赋值:L-5日前的L的绝对值<=L0


精准线赋值:L1 OR L2 OR L3 OR L4 OR L5
输出

底精准: 精准线的NN过滤,画青色
输出

 

{6.2 异向并肩精准线}

异向并肩精准: O和C的较小值=REF(O和C较大值,1)


{4.咬住峰顶线}

FDX赋值:PEAK(1,10,1)
{REF(60日内H最高值,5)}
{上一波峰值}

TJ赋值:BETWEEN(H的3日简单移动平均,FDX*0.997,FDX*1.02)
输出

咬住峰顶线: 统计3日满足TJ的天数>=2,画红色